summaryrefslogtreecommitdiff
path: root/src/contrib/SDL-3.2.20/examples/CMakeLists.txt
diff options
context:
space:
mode:
Diffstat (limited to 'src/contrib/SDL-3.2.20/examples/CMakeLists.txt')
-rw-r--r--src/contrib/SDL-3.2.20/examples/CMakeLists.txt382
1 files changed, 382 insertions, 0 deletions
diff --git a/src/contrib/SDL-3.2.20/examples/CMakeLists.txt b/src/contrib/SDL-3.2.20/examples/CMakeLists.txt
new file mode 100644
index 0000000..2a13a03
--- /dev/null
+++ b/src/contrib/SDL-3.2.20/examples/CMakeLists.txt
@@ -0,0 +1,382 @@
1#
2# CMake script for building the SDL examples
3#
4
5list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_LIST_DIR}/../cmake")
6
7include(CheckIncludeFile)
8include(CheckStructHasMember)
9include(CMakePushCheckState)
10include(sdlcompilers)
11
12if(SDL_EXAMPLES_LINK_SHARED)
13 set(sdl_name_component SDL3-shared)
14else()
15 set(sdl_name_component SDL3-static)
16endif()
17set(HAVE_EXAMPLES_LINK_SHARED "${SDL_EXAMPLES_LINK_SHARED}" PARENT_SCOPE)
18
19# CMake incorrectly detects opengl32.lib being present on MSVC ARM64
20if(NOT (MSVC AND SDL_CPU_ARM64))
21 # Prefer GLVND, if present
22 set(OpenGL_GL_PREFERENCE GLVND)
23 find_package(OpenGL)
24endif()
25
26set(SDL_EXAMPLE_EXECUTABLES)
27
28if(CMAKE_RUNTIME_OUTPUT_DIRECTORY)
29 set(example_bin_dir "${CMAKE_RUNTIME_OUTPUT_DIRECTORY}")
30 if(NOT IS_ABSOLUTE "${CMAKE_RUNTIME_OUTPUT_DIRECTORY}")
31 set(example_bin_dir "${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_RUNTIME_OUTPUT_DIRECTORY}")
32 endif()
33else()
34 set(example_bin_dir "${CMAKE_CURRENT_BINARY_DIR}")
35endif()
36if(NOT CMAKE_VERSION VERSION_LESS 3.20)
37 get_property(is_multi_config GLOBAL PROPERTY GENERATOR_IS_MULTI_CONFIG)
38 set(example_bin_dir "${example_bin_dir}$<$<BOOL:${is_multi_config}>:/$<CONFIG>>")
39endif()
40
41file(GLOB RESOURCE_FILES ${CMAKE_CURRENT_SOURCE_DIR}/../test/*.bmp ${CMAKE_CURRENT_SOURCE_DIR}/../test/*.wav ${CMAKE_CURRENT_SOURCE_DIR}/../test/*.hex)
42
43set(RESOURCE_FILE_NAMES)
44set(RESOURCE_FILES_BINDIR)
45foreach(resource_file IN LISTS RESOURCE_FILES)
46 get_filename_component(res_file_name ${resource_file} NAME)
47 list(APPEND RESOURCE_FILE_NAMES "${res_file_name}")
48 set(resource_file_bindir "${example_bin_dir}/${res_file_name}")
49 add_custom_command(OUTPUT "${resource_file_bindir}"
50 COMMAND "${CMAKE_COMMAND}" -E copy "${resource_file}" "${resource_file_bindir}"
51 DEPENDS "${resource_file}"
52 )
53 list(APPEND RESOURCE_FILES_BINDIR "${resource_file_bindir}")
54endforeach()
55add_custom_target(copy-sdl-example-resources
56 DEPENDS "${RESOURCE_FILES_BINDIR}"
57)
58
59macro(add_sdl_example_executable TARGET)
60 cmake_parse_arguments(AST "BUILD_DEPENDENT" "" "SOURCES;DATAFILES" ${ARGN})
61 if(AST_UNPARSED_ARGUMENTS)
62 message(FATAL_ERROR "Unknown argument(s): ${AST_UNPARSED_ARGUMENTS}")
63 endif()
64 if(NOT AST_SOURCES)
65 message(FATAL_ERROR "add_sdl_example_executable needs at least one source")
66 endif()
67 set(EXTRA_SOURCES "")
68 if(AST_DATAFILES)
69 list(APPEND EXTRA_SOURCES ${DATAFILES})
70 endif()
71 if(ANDROID)
72 add_library(${TARGET} SHARED ${AST_SOURCES} ${EXTRA_SOURCES})
73 else()
74 add_executable(${TARGET} ${AST_SOURCES} ${EXTRA_SOURCES})
75 endif()
76 SDL_AddCommonCompilerFlags(${TARGET})
77 target_include_directories(${TARGET} PRIVATE "${SDL3_SOURCE_DIR}/src/video/khronos")
78 target_link_libraries(${TARGET} PRIVATE SDL3::${sdl_name_component})
79
80 list(APPEND SDL_EXAMPLE_EXECUTABLES ${TARGET})
81 if(AST_DATAFILES)
82 if(PSP OR PS2)
83 add_custom_command(TARGET ${TARGET} POST_BUILD
84 COMMAND ${CMAKE_COMMAND} ARGS -E make_directory $<TARGET_FILE_DIR:${TARGET}>/sdl-${TARGET}
85 COMMAND ${CMAKE_COMMAND} ARGS -E copy_if_different ${AST_DATAFILES} $<TARGET_FILE_DIR:${TARGET}>/sdl-${TARGET}
86 WORKING_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}"
87 )
88 else()
89 add_dependencies(${TARGET} copy-sdl-example-resources)
90 endif()
91 if(APPLE)
92 # Make sure resource files get installed into macOS/iOS .app bundles.
93 set_target_properties(${TARGET} PROPERTIES RESOURCE "${AST_DATAFILES}")
94 endif()
95 if(EMSCRIPTEN)
96 foreach(res IN LISTS AST_DATAFILES)
97 get_filename_component(res_name "${res}" NAME)
98 target_link_options(${TARGET} PRIVATE "SHELL:--embed-file ${res}@${res_name}")
99 endforeach()
100 endif()
101 set_property(TARGET ${TARGET} APPEND PROPERTY ADDITIONAL_CLEAN_FILES "$<TARGET_FILE_DIR:${TARGET}>/$<JOIN:${AST_DATAFILES},$<SEMICOLON>$<TARGET_FILE_DIR:${TARGET}>/>")
102 endif()
103
104 if(WINDOWS)
105 # CET support was added in VS 16.7
106 if(MSVC_VERSION GREATER 1926 AND CMAKE_GENERATOR_PLATFORM MATCHES "Win32|x64")
107 set_property(TARGET ${TARGET} APPEND_STRING PROPERTY LINK_FLAGS " -CETCOMPAT")
108 endif()
109 elseif(PSP)
110 target_link_libraries(${TARGET} PRIVATE GL)
111 elseif(EMSCRIPTEN)
112 set_property(TARGET ${TARGET} PROPERTY SUFFIX ".html")
113 target_link_options(${TARGET} PRIVATE -sALLOW_MEMORY_GROWTH=1)
114 endif()
115
116 if(OPENGL_FOUND)
117 target_compile_definitions(${TARGET} PRIVATE HAVE_OPENGL)
118 endif()
119
120 # FIXME: only add "${SDL3_BINARY_DIR}/include-config-$<LOWER_CASE:$<CONFIG>>" + include paths of external dependencies
121 target_include_directories(${TARGET} PRIVATE "$<TARGET_PROPERTY:SDL3::${sdl_name_component},INCLUDE_DIRECTORIES>")
122endmacro()
123
124add_sdl_example_executable(renderer-clear SOURCES renderer/01-clear/clear.c)
125add_sdl_example_executable(renderer-primitives SOURCES renderer/02-primitives/primitives.c)
126add_sdl_example_executable(renderer-lines SOURCES renderer/03-lines/lines.c)
127add_sdl_example_executable(renderer-points SOURCES renderer/04-points/points.c)
128add_sdl_example_executable(renderer-rectangles SOURCES renderer/05-rectangles/rectangles.c)
129add_sdl_example_executable(renderer-textures SOURCES renderer/06-textures/textures.c DATAFILES ${CMAKE_CURRENT_SOURCE_DIR}/../test/sample.bmp)
130add_sdl_example_executable(renderer-streaming-textures SOURCES renderer/07-streaming-textures/streaming-textures.c)
131add_sdl_example_executable(renderer-rotating-textures SOURCES renderer/08-rotating-textures/rotating-textures.c DATAFILES ${CMAKE_CURRENT_SOURCE_DIR}/../test/sample.bmp)
132add_sdl_example_executable(renderer-scaling-textures SOURCES renderer/09-scaling-textures/scaling-textures.c DATAFILES ${CMAKE_CURRENT_SOURCE_DIR}/../test/sample.bmp)
133add_sdl_example_executable(renderer-geometry SOURCES renderer/10-geometry/geometry.c DATAFILES ${CMAKE_CURRENT_SOURCE_DIR}/../test/sample.bmp)
134add_sdl_example_executable(renderer-color-mods SOURCES renderer/11-color-mods/color-mods.c DATAFILES ${CMAKE_CURRENT_SOURCE_DIR}/../test/sample.bmp)
135add_sdl_example_executable(renderer-viewport SOURCES renderer/14-viewport/viewport.c DATAFILES ${CMAKE_CURRENT_SOURCE_DIR}/../test/sample.bmp)
136add_sdl_example_executable(renderer-cliprect SOURCES renderer/15-cliprect/cliprect.c DATAFILES ${CMAKE_CURRENT_SOURCE_DIR}/../test/sample.bmp)
137add_sdl_example_executable(renderer-read-pixels SOURCES renderer/17-read-pixels/read-pixels.c DATAFILES ${CMAKE_CURRENT_SOURCE_DIR}/../test/sample.bmp)
138add_sdl_example_executable(renderer-debug-text SOURCES renderer/18-debug-text/debug-text.c)
139add_sdl_example_executable(audio-simple-playback SOURCES audio/01-simple-playback/simple-playback.c)
140add_sdl_example_executable(audio-simple-playback-callback SOURCES audio/02-simple-playback-callback/simple-playback-callback.c)
141add_sdl_example_executable(audio-load-wav SOURCES audio/03-load-wav/load-wav.c DATAFILES ${CMAKE_CURRENT_SOURCE_DIR}/../test/sample.wav)
142add_sdl_example_executable(audio-multiple-streams SOURCES audio/04-multiple-streams/multiple-streams.c DATAFILES ${CMAKE_CURRENT_SOURCE_DIR}/../test/sample.wav ${CMAKE_CURRENT_SOURCE_DIR}/../test/sword.wav)
143add_sdl_example_executable(input-joystick-polling SOURCES input/01-joystick-polling/joystick-polling.c)
144add_sdl_example_executable(input-joystick-events SOURCES input/02-joystick-events/joystick-events.c)
145add_sdl_example_executable(camera-read-and-draw SOURCES camera/01-read-and-draw/read-and-draw.c)
146add_sdl_example_executable(pen-drawing-lines SOURCES pen/01-drawing-lines/drawing-lines.c)
147add_sdl_example_executable(asyncio-load-bitmaps SOURCES asyncio/01-load-bitmaps/load-bitmaps.c DATAFILES ${CMAKE_CURRENT_SOURCE_DIR}/../test/sample.bmp ${CMAKE_CURRENT_SOURCE_DIR}/../test/gamepad_front.bmp ${CMAKE_CURRENT_SOURCE_DIR}/../test/speaker.bmp ${CMAKE_CURRENT_SOURCE_DIR}/../test/icon2x.bmp)
148add_sdl_example_executable(demo-snake SOURCES demo/01-snake/snake.c)
149add_sdl_example_executable(demo-woodeneye-008 SOURCES demo/02-woodeneye-008/woodeneye-008.c)
150add_sdl_example_executable(demo-infinite-monkeys SOURCES demo/03-infinite-monkeys/infinite-monkeys.c)
151add_sdl_example_executable(demo-bytepusher SOURCES demo/04-bytepusher/bytepusher.c)
152
153# When you add an example, remember to add the Visual Studio project as well:
154# - Add a new example in examples/
155# - Run python VisualC/examples/generate.py
156# - Take note of the newly generated .vcxproj files
157# - Modify the .vcxproj files if necessary (adding content such as BMP or WAV files)
158# - Open VisualC/SDL.sln in Visual Studio or JetBrains Rider
159# - Locate the appropriate folder in the Solution Explorer
160# - Add the newly generated projects: Right click -> Add -> Existing project...
161# - Test if they work
162# - Save the SDL.sln solution
163
164if(PSP)
165 # Build EBOOT files if building for PSP
166 foreach(APP ${SDL_EXAMPLE_EXECUTABLES})
167 create_pbp_file(
168 TARGET ${APP}
169 TITLE SDL-${APP}
170 ICON_PATH NULL
171 BACKGROUND_PATH NULL
172 PREVIEW_PATH NULL
173 OUTPUT_DIR $<TARGET_FILE_DIR:${APP}>/sdl-${APP}
174 )
175 endforeach()
176endif()
177
178if(N3DS)
179 set(ROMFS_DIR "${CMAKE_CURRENT_BINARY_DIR}/romfs")
180 file(MAKE_DIRECTORY "${ROMFS_DIR}")
181 file(COPY ${RESOURCE_FILES} DESTINATION "${ROMFS_DIR}")
182
183 foreach(APP ${SDL_EXAMPLE_EXECUTABLES})
184 get_target_property(TARGET_BINARY_DIR ${APP} BINARY_DIR)
185 set(SMDH_FILE "${TARGET_BINARY_DIR}/${APP}.smdh")
186 ctr_generate_smdh("${SMDH_FILE}"
187 NAME "SDL-${APP}"
188 DESCRIPTION "SDL3 Test suite"
189 AUTHOR "SDL3 Contributors"
190 ICON "${CMAKE_CURRENT_SOURCE_DIR}/../test/n3ds/logo48x48.png"
191 )
192 ctr_create_3dsx(
193 ${APP}
194 ROMFS "${ROMFS_DIR}"
195 SMDH "${SMDH_FILE}"
196 )
197 endforeach()
198endif()
199
200if(RISCOS)
201 set(SDL_EXAMPLE_EXECUTABLES_AIF)
202 foreach(APP ${SDL_EXAMPLE_EXECUTABLES})
203 set_property(TARGET ${APP} APPEND_STRING PROPERTY LINK_FLAGS " -static")
204 add_custom_command(
205 OUTPUT ${APP},ff8
206 COMMAND elf2aif ${APP} ${APP},ff8
207 DEPENDS ${APP}
208 )
209 add_custom_target(${APP}-aif ALL DEPENDS ${APP},ff8)
210 list(APPEND SDL_EXAMPLE_EXECUTABLES_AIF ${CMAKE_CURRENT_BINARY_DIR}/${APP},ff8)
211 endforeach()
212endif()
213
214# Set Apple App ID / Bundle ID. This is needed to launch apps on some Apple
215# platforms (iOS, for example).
216if(APPLE)
217 foreach(CURRENT_TARGET ${SDL_EXAMPLE_EXECUTABLES})
218 set_target_properties("${CURRENT_TARGET}" PROPERTIES
219 MACOSX_BUNDLE_GUI_IDENTIFIER "org.libsdl.${CURRENT_TARGET}"
220 MACOSX_BUNDLE_BUNDLE_VERSION "${SDL3_VERSION}"
221 MACOSX_BUNDLE_SHORT_VERSION_STRING "${SDL3_VERSION}"
222 )
223 endforeach()
224endif()
225
226if(SDL_INSTALL_EXAMPLES)
227 if(RISCOS)
228 install(
229 FILES ${SDL_EXAMPLE_EXECUTABLES_AIF}
230 DESTINATION ${CMAKE_INSTALL_LIBEXECDIR}/installed-examples/SDL3
231 )
232 else()
233 install(
234 TARGETS ${SDL_EXAMPLE_EXECUTABLES}
235 DESTINATION ${CMAKE_INSTALL_LIBEXECDIR}/installed-examples/SDL3
236 )
237 endif()
238 if(MSVC)
239 foreach(example IN LISTS SDL_EXAMPLE_EXECUTABLES)
240 SDL_install_pdb(${example} "${CMAKE_INSTALL_LIBEXECDIR}/installed-examples/SDL3")
241 endforeach()
242 endif()
243 install(
244 FILES ${RESOURCE_FILES}
245 DESTINATION ${CMAKE_INSTALL_LIBEXECDIR}/installed-examples/SDL3
246 )
247endif()
248
249if(ANDROID AND TARGET SDL3::Jar)
250 list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_LIST_DIR}/../cmake/android")
251 find_package(SdlAndroid MODULE)
252 if(SdlAndroid_FOUND)
253 set(apks "")
254 set(packages "")
255
256 include(SdlAndroidFunctions)
257 sdl_create_android_debug_keystore(SDL_example-debug-keystore)
258 sdl_android_compile_resources(SDL_example-resources RESFOLDER ${CMAKE_CURRENT_SOURCE_DIR}/../test/android/res)
259 add_custom_target(sdl-example-apks)
260 foreach(EXAMPLE ${SDL_EXAMPLE_EXECUTABLES})
261 set(ANDROID_MANIFEST_APP_NAME "${EXAMPLE}")
262 set(ANDROID_MANIFEST_LABEL "${EXAMPLE}")
263 set(ANDROID_MANIFEST_LIB_NAME "$<TARGET_FILE_BASE_NAME:${EXAMPLE}>")
264 set(ANDROID_MANIFEST_PACKAGE "org.libsdl.sdl.example.${EXAMPLE}")
265 set(generated_manifest_path "${CMAKE_CURRENT_BINARY_DIR}/android/${EXAMPLE}-src/AndroidManifest.xml")
266 string(REPLACE "." "/" JAVA_PACKAGE_DIR "${ANDROID_MANIFEST_PACKAGE}")
267 set(GENERATED_SRC_FOLDER "${CMAKE_CURRENT_BINARY_DIR}/android/${EXAMPLE}-src")
268 set(GENERATED_RES_FOLDER "${GENERATED_SRC_FOLDER}/res")
269 set(JAVA_PACKAGE_DIR "${GENERATED_SRC_FOLDER}/${JAVA_PACKAGE_DIR}")
270 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/../test/android/cmake/SDLEntryTestActivity.java.cmake "${JAVA_PACKAGE_DIR}/SDLEntryTestActivity.java" @ONLY)
271 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/../test/android/cmake/SDLTestActivity.java.cmake "${JAVA_PACKAGE_DIR}/SDLTestActivity.java" @ONLY)
272 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/../test/android/cmake/res/values/strings.xml.cmake android/res/values/strings-${EXAMPLE}.xml @ONLY)
273 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/../test/android/cmake/res/xml/shortcuts.xml.cmake "${GENERATED_RES_FOLDER}/xml/shortcuts.xml" @ONLY)
274 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/../test/android/cmake/AndroidManifest.xml.cmake "${generated_manifest_path}" @ONLY)
275 file(GENERATE
276 OUTPUT "${CMAKE_CURRENT_BINARY_DIR}/android/${EXAMPLE}-$<CONFIG>/res/values/strings.xml"
277 INPUT "${CMAKE_CURRENT_BINARY_DIR}/android/res/values/strings-${EXAMPLE}.xml"
278 )
279
280 sdl_android_compile_resources(${EXAMPLE}-resources
281 RESOURCES
282 "${CMAKE_CURRENT_BINARY_DIR}/android/${EXAMPLE}-$<CONFIG>/res/values/strings.xml"
283 "${GENERATED_RES_FOLDER}/xml/shortcuts.xml"
284 )
285
286 sdl_android_link_resources(${EXAMPLE}-apk-linked
287 MANIFEST "${generated_manifest_path}"
288 PACKAGE ${ANDROID_MANIFEST_PACKAGE}
289 RES_TARGETS SDL_example-resources ${EXAMPLE}-resources
290 TARGET_SDK_VERSION 31
291 )
292
293 set(CMAKE_JAVA_COMPILE_FLAGS "-encoding;utf-8")
294 set(classes_path "${CMAKE_CURRENT_BINARY_DIR}/CMakeFiles/${EXAMPLE}-java.dir/classes")
295 # Some CMake versions have a slow `cmake -E make_directory` implementation
296 if(NOT IS_DIRECTORY "${classes_path}")
297 execute_process(COMMAND ${CMAKE_COMMAND} -E make_directory "${classes_path}")
298 endif()
299 set(OUT_JAR "${CMAKE_CURRENT_BINARY_DIR}/${EXAMPLE}.jar")
300 add_custom_command(
301 OUTPUT "${OUT_JAR}"
302 COMMAND ${CMAKE_COMMAND} -E rm -rf "${classes_path}"
303 COMMAND ${CMAKE_COMMAND} -E make_directory "${classes_path}"
304 COMMAND ${Java_JAVAC_EXECUTABLE}
305 -source 1.8 -target 1.8
306 -bootclasspath "$<TARGET_PROPERTY:SDL3::Jar,JAR_FILE>"
307 "${JAVA_PACKAGE_DIR}/SDLEntryTestActivity.java"
308 "${JAVA_PACKAGE_DIR}/SDLTestActivity.java"
309 $<TARGET_PROPERTY:${EXAMPLE}-apk-linked,JAVA_R>
310 -cp "$<TARGET_PROPERTY:SDL3::Jar,JAR_FILE>:${SDL_ANDROID_PLATFORM_ANDROID_JAR}"
311 -d "${classes_path}"
312 COMMAND ${Java_JAR_EXECUTABLE} cf "${OUT_JAR}" -C "${classes_path}" .
313 DEPENDS $<TARGET_PROPERTY:${EXAMPLE}-apk-linked,OUTPUTS> "$<TARGET_PROPERTY:SDL3::Jar,JAR_FILE>" "${JAVA_PACKAGE_DIR}/SDLTestActivity.java" "${JAVA_PACKAGE_DIR}/SDLEntryTestActivity.java"
314 )
315 add_custom_target(${EXAMPLE}-jar DEPENDS "${OUT_JAR}")
316 set_property(TARGET ${EXAMPLE}-jar PROPERTY OUTPUT "${OUT_JAR}")
317
318 set(dexworkdir "${CMAKE_CURRENT_BINARY_DIR}/CMakeFiles/${EXAMPLE}-dex.dir")
319 # Some CMake versions have a slow `cmake -E make_directory` implementation
320 if(NOT IS_DIRECTORY "${dexworkdir}")
321 execute_process(COMMAND "${CMAKE_COMMAND}" -E make_directory "${dexworkdir}")
322 endif()
323 set(classes_dex_base_name "classes.dex")
324 set(classes_dex "${dexworkdir}/${classes_dex_base_name}")
325 add_custom_command(
326 OUTPUT "${classes_dex}"
327 COMMAND SdlAndroid::d8
328 $<TARGET_PROPERTY:${EXAMPLE}-jar,OUTPUT>
329 $<TARGET_PROPERTY:SDL3::Jar,JAR_FILE>
330 --lib "${SDL_ANDROID_PLATFORM_ANDROID_JAR}"
331 --output "${dexworkdir}"
332 DEPENDS $<TARGET_PROPERTY:${EXAMPLE}-jar,OUTPUT> $<TARGET_PROPERTY:SDL3::Jar,JAR_FILE>
333 )
334 add_custom_target(${EXAMPLE}-dex DEPENDS "${classes_dex}")
335 set_property(TARGET ${EXAMPLE}-dex PROPERTY OUTPUT "${classes_dex}")
336 set_property(TARGET ${EXAMPLE}-dex PROPERTY OUTPUT_BASE_NAME "${classes_dex_base_name}")
337
338 sdl_add_to_apk_unaligned(${EXAMPLE}-unaligned-apk
339 APK_IN ${EXAMPLE}-apk-linked
340 OUTDIR "${CMAKE_CURRENT_BINARY_DIR}/intermediates"
341 ASSETS ${RESOURCE_FILES}
342 NATIVE_LIBS SDL3::SDL3-shared ${EXAMPLE}
343 DEX ${EXAMPLE}-dex
344 )
345
346 sdl_apk_align(${EXAMPLE}-aligned-apk ${EXAMPLE}-unaligned-apk
347 OUTDIR "${CMAKE_CURRENT_BINARY_DIR}/intermediates"
348 )
349 sdl_apk_sign(${EXAMPLE}-apk ${EXAMPLE}-aligned-apk
350 KEYSTORE SDL_example-debug-keystore
351 )
352 add_dependencies(sdl-example-apks ${EXAMPLE}-apk)
353
354 if(TARGET SdlAndroid::adb)
355 add_custom_target(install-${EXAMPLE}
356 COMMAND "${CMAKE_COMMAND}" -DACTION=install "-DAPKS=$<TARGET_PROPERTY:${EXAMPLE}-apk,OUTPUT>" -P "${SDL3_SOURCE_DIR}/cmake/android/SdlAndroidScript.cmake"
357 DEPENDS "${EXAMPLE}-apk"
358 )
359 add_custom_target(start-${EXAMPLE}
360 COMMAND "${ADB_BIN}" shell am start-activity -S "${ANDROID_MANIFEST_PACKAGE}/.SDLTestActivity"
361 )
362 add_custom_target(build-install-start-${EXAMPLE}
363 COMMAND "${CMAKE_COMMAND}" -DACTION=build-install-run "-DEXECUTABLES=${EXAMPLE}" "-DBUILD_FOLDER=${CMAKE_BINARY_DIR}" -P "${SDL3_SOURCE_DIR}/cmake/android/SdlAndroidScript.cmake"
364 )
365 endif()
366
367 list(APPEND packages "${ANDROID_MANIFEST_PACKAGE}")
368 list(APPEND install_targets install-${EXAMPLE})
369 endforeach()
370
371 if(TARGET SdlAndroid::adb)
372 add_custom_target(install-sdl-example-apks
373 DEPENDS ${install_targets}
374 VERBATIM
375 )
376 add_custom_target(uninstall-sdl-example-apks
377 COMMAND "${CMAKE_COMMAND}" "-DADB=$<TARGET_FILE:SdlAndroid::adb>" -DACTION=uninstall "-DPACKAGES=${packages}" -P "${SDL3_SOURCE_DIR}/cmake/android/SdlAndroidScript.cmake"
378 VERBATIM
379 )
380 endif()
381 endif()
382endif()
generated by cgit v1.2.3 (git 2.25.1) at 2025-09-13 19:14:36 +0000